▧ 14일: 문법


▷ A13. 문법 (Grammar)
  아래는 이 부록의 앞부분에 나왔던 문법을 요약한 것입니다. 내용은 앞에서 다룬 것과 동일하지만, 순서는 바뀌었습니다.
  이 문법에서는, 종료자 기호 (terminal symbol) 인 integer-constant (정수상수), character-constant (문자상수), floating-constant (부동상수), identifier (명칭), string (문자열), enumeration-constant (열거상수) 를 정의하지 않았습니다; 타이프체 (typewriter style) 단어와 기호는 문법적으로 주어진 종료자 (terminal) 입니다. 이 문법은 자동 파서-생성기 (automatic parser-generator) 가 받아들일 수 있는 입력형태로 변환이 가능합니다.

▶ 역자 주
  파서-생성기 (parser-generator) 란, 문법구조를 받아들여 그 언어의 파서 (parser) 프로그램을 생성해 주는 것입니다. 프로그래밍 언어를 정교하게 이론화하면, 이러한 작업을 자동화할 수 있습니다. 대표적인 것으로는 YACC 가 있습니다.

  파서 (parser) 란, 컴파일러나 인터프리터에서 원시 프로그램을 읽어들여, 그 문장의 구조를 알아내는 구문분석 (parsing) 을 행하는 프로그램을 말합니다.

  구문분석 (parsing) 이란, 컴파일러나 인터프리터가 프로그램을 이해해 기계어로 번역하는 과정중의 한단계로, 각 문장의 문법적 구성·구문을 분석하는 과정입니다. 정확하게 이야기하면, 원시 프로그램의 토큰열 (token sequence) 을 받아들여 문법에 맞게 파스 트리 (parse tree) 로 구성하는 것을 말합니다. 구문분석의 종류에는 다음과 같은 것들이 있습니다:

하향식 파싱 (top-down parsing)
상향식 파싱 (bottom-up parsing)
재귀 하강식 파싱 (recursive descendent parsing)
예측형 파싱 (predictive parsing)
픽쳐 파싱 (picture parsing)
연산자 우선순위 파싱 (operator precedence parsing)
LR 파싱 (LR parsing)

문법으로 제시된 것에 대체가능함 (alternative) 을 의미하는 문법적 표시 (syntactic marking) 를 사용해주고, "one of" 구조를 확장하고, (파서-생성기의 규칙에 따라) opt 기호가 붙은 것을 한번은 기호와 함께, 한번은 기호없이 복사해 써줄 필요가 있습니다.

▶ 역자 주
  예를 들어 설명하면, 다음과 같이 바꿔줘야 한다는 것입니다. (아래에서 기호 | 는 'or' 을 의미합니다)

(원래) struct-or-union:   one of
        struct         union
(수정후)   struct-or-union:
        struct    |    union
 
(원래) declarator:
        pointer opt   direct-declarator
(수정후) declarator:
        pointer   direct-declarator
        direct-declarator
 

또한, typedef-name: identifier 로 제시된 것을 없애고, typedef-name 을 종료자 기호 (terminal symbol) 로 만들면, 이 문법은 YACC 파서-생성기 (YACC parser-generator) 가 받아들일 수 있게 됩니다.

▶ 역자 주
  YACC 는, "Yet Another Compiler-Compiler" 의 약자로, 유닉스 운영체제에서 돌아가는 파서-생성기의 이름입니다. 원하는 구문 (syntax) 을 백커스 정규형 (BNF) 으로 입력하면, 그에 해당하는 파서 (parser) 를 C 언어로 만들어 줍니다.

  백커스 정규형 (Backus Normal Form 혹은 Backus-Nour Form) 은, 백커스 (P.Backus) 와 나우어 (P.Nour) 가 중심이 된 위원회에서 ALGOL 60 언어의 문법구조를 정리하기 위해 만든 형식입니다. 1963년 출판된 ALGOL 60 보고서에 처음으로 사용되었으며, 비종료자 기호로부터 종료자 기호와 비종료자 기호로 이루어진 기호열 (symbol sequence) 을 도출하는 생성규칙 (production) 으로 언어의 문법을 정리하도록 되어 있습니다. 이는 언어의 문법 구조만을 설명해 주는 것이며, 각각의 의미를 알려주지는 않습니다.

이 문법에는, if-else 모호함에 의해 발생하는 충돌 (conflict) 이 하나 존재합니다.

▶ 역자 주
  여기서 말하는 충돌 (conflict) 이란, 선택 가능성이 (한개만 존재해야 하는데) 여러개 존재하는 것을 의미합니다. 즉, 이곳에서 제시된 if 문의 문법을 살펴보면 다음과 같습니다. (원래 있는 switch 문은 생략했습니다)

selection-statment:
          if ( expression ) statement
          if ( expression ) else statement

위와 같이 문법이 주어진 상태에서, 다음과 같은 문장은

if (expr_1) if (expr_2) stmt_1 else stmt_2

각각 아래와 같이 두가지 의미로 해석될 수 있습니다.

if (expr_1) {
      if (expr_2)                  
            stmt_1
      else
            stmt_2
}		 if (expr_1) {
      if (expr_2)
            stmt_1
}
else
      stmt_2

이러한 충돌을 해결하려면, 두개의 비종료자 기호 (non-terminal symbol) 를 추가해야 합니다.

  아래는 문법 요약입니다. 한줄에 나와야 하는 것이 부득이한 사정으로 두줄로 나누어진 경우, 라인 연결의 의미를 갖는 \ 문자를 사용해서 표시했습니다.

translation-unit:
        external-declaration
        translation-unit  external-declaration

external-declaration:
        function-definition
        declaration

function-definition:
        declaration-specifiersopt  declarator  \
                                    declaration-listopt  compound-statement

declaration:
        declaration-specifiers  init-declarator-listopt  ;

declaration-list:
        declaration
        declaration-list  declaration

declaration-specifiers:
        storage-class-specifier  declaration-specifiersopt
        type-specifier  declaration-specifiersopt
        type-qualifier  declaration-specifiersopt

storage-class-specifier:   one of
        auto  register  static  extern  typedef

type-specifier:   one of
        void  char  short  int  long  float  double
        signed  unsigned   struct-or-union-specifier
        enum-specifier   typedef-name

type-qualifier:   one of
        const  volatile

struct-or-union-specifier:
        struct-or-union  identifieropt  {  struct-declaration-list  }
        struct-or-union  identifier

struct-or-union:   one of
        struct  union

struct-declaration-list:
        struct-declaration
        struct-declaration-list  struct-declaration

init-declarator-list:
        init-declarator
        init-declarator-list  ,  init-declarator

init-declarator:
        declarator
        declarator  =  initializer

struct-declaration:
        specifier-qualifier-list  struct-declarator-list  ;

specifier-qualifier-list:
        type-specifier  specifier-qualifier-listopt
        type-qualifier  specifier-qualifier-listopt

struct-declarator-list:
        struct-declarator
        struct-declarator-list  ,  struct-declarator

struct-declarator:
        declarator
        declaratoropt  :  constant-expression

enum-specifier:
        enum  identifieropt  {  enumerator-list  }
        enum  identifier

enumerator-list:
        enumerator
        enumerator-list  ,  enumerator

enumerator:
        identifier
        identifier  =  constant-expression

declarator:
        pointeropt  direct-declarator

direct-declarator:
        identifier
        ( declarator )
        direct-declarator  [  constant-expressionopt  ]
        direct-declarator  (  parameter-type-list  )
        direct-declarator  (  identifier-listopt  )

pointer:
        *  type-qualifier-listopt
        *  type-qualifier-listopt  pointer

type-qualifier-list:
        type-qualifier
        type-qualifier-list  type-qualifier

parameter-type-list:
        parameter-list
        parameter-list  , ...

parameter-list:
        parameter-declaration
        parameter-list  ,  parameter-declaration

parameter-declaration:
        declaration-specifier  declarator
        declaration-specifier  abstract-declaratoropt

identifier-list:
        identifier
        identifier-list  ,  identifier

initializer:
        assignment-expression
        {  initializer-list  }
        {  initializer-list  , }

initializer-list:
        initializer
        initializer-list  ,  initializer

type-name:
        specifier-qualifier-list  abstract-declaratoropt

abstract-declarator:
        pointer
        pointeropt  direct-abstract-declarator

direct-abstract-declarator:
        ( abstract-declarator )
        direct-abstract-declaratoropt  [  constant-expressionopt  ]
        direct-abstract-declaratoropt  (  parameter-type-listopt  )

typedef-name:
        identifier

statement:
        labeled-statement
        expression-statement
        compound-statement
        selection-statement
        iteration-statement
        jump-statement

labeled-statement:
        identifier  :  statement
        case  constant-expression  :  statement
        default  :  statement

expression-statement:
        expressionopt  ;

compound-statement:
        {  declaration-listopt  statement-listopt  }

statement-list:
        statement
        statement-list  statement

selection-statement:
        if  ( expression )  statement
        if  ( expression )  statement  else  statement
        switch  ( expression )  statement

iteration-statement:
        while  ( expression )  statement
        do  statement  while  ( expression )  ;
        for  ( expressionopt  ;  expressionopt  ;  exrepssionopt )  statement

jump-statement:
        goto  identifier  ;
        continue  ;
        break  ;
        return expressionopt  ;

expression:
        assignment-expression
        expression  ,  assignment-expression

assignment-expression:
        conditional-expression
        unary-expression  assignment-operator  assignment-expression

assignment-operator:   one of
        =  *=  /=  %=  +=  -=  <<=  >>=  &=  ^=  |=

conditional-expression:
        logical-OR-expression
        logical-OR-expression  ?  expression  :  conditional-expression

constant-expression:
        conditional-expression

logical-OR-expression:
        logical-AND-expression
        logical-OR-expression  ||  logical-AND-expression

logical-AND-expression:
        inclusive-OR-expression
        logical-AND-expression  &&  inclusive-OR-expression

inclusive-OR-expression:
        exclusive-OR-expression
        inclusive-OR-expression  |  exclusive-OR-expression

exclusive-OR-expression:
        AND-expression
        exclusive-OR-expression  ^  AND-expression

AND-expression:
        equality-expression
        AND-expression  &  equality-expression

equality-expression:
        relational-expression
        equality-expression  ==  relational-expression
        equality-expression  !=  relational-expression

relational-expression:
        shift-expression
        relational-expression  <  shift-expression
        relational-expression  >  shift-expression
        relational-expression  <=  shift-expression
        relational-expression  >=  shift-expression

shift-expression:
        additive-expression
        shift-expression  <<  additive-expression
        shift-expression  >>  additive-expression

additive-expression:
        multiplicative-expression
        additive-expression  +  multiplicative-expression
        additive-expression  -  multiplicative-expression

multiplicative-expression:
        cast-expression
        multiplicative-expression  *  cast-expression
        multiplicative-expression  /  cast-expression
        multiplicative-expression  %  cast-expression

cast-expression:
        unary-expression
        ( type-name )  cast-expression

unary-expression:
        postfix-expression
        ++  unary-expression
        --  unary-expression
        unary-operator  cast-expression
        sizeof  unary-expression
        sizeof  ( type-name )

unary-operator:   one of
        &  *  +  -  ~  !

postfix-expression:
        primary-expression
        postfix-expression  [  expression  ]
        postfix-expression  (  argument-expression-listopt  )
        postfix-expression  .  identifier
        postfix-expression  ->  identifier
        postfix-expression  ++
        postfix-expression  --

primary-expression:
        identifier
        constant
        string
        ( expression )

argument-expression-list:
        assignment-expression
        argument-expression-list  ,  assignment-expression

constant:
        integer-constant
        character-constant
        floating-constant
        enumeration-constant

  아래에 주어진 전처리기 (preprocessor) 에 대한 문법은 제어라인 (control line) 의 구조를 요약한 것이며, 구문분석 (parsing) 에 사용하기에는 적합하지 않습니다. 여기에는, 텍스트 (text) 라는 기호 (symbol) 가 포함되어 있으며, 이 텍스트 (text) 는 일반 프로그램 텍스트 (ordinary program text), 비조건부 컴파일 제어라인 (non-conditional preprocessor control line), 완전한 조건부 컴파일 구조 (complete preprocessor conditional construction) 를 의미합니다. 여기서도 역시 부득이한 사정으로 두줄로 나눠진 경우에는 \ 를 사용해 표시하였습니다.

control-line:
        #  define  identifier  token-sequence
        #  define  identifier( identifieropt  , ...  \
                                          , identifieropt )  token-sequence
        #  undef  identifier
        #  include  <filename>
        #  include  "identifier"
        #  include  token-sequence
        #  line  constant  "filename"
        #  line  constant
        #  error  token-sequenceopt
        #  pragma  token-sequenceopt
        #
        preprocessor-conditional

preprocessor-conditional:
        if-line  text  elif-parts  else-partopt  #  endif

if-line:
        #  if  constant-expression
        #  ifdef  identifier
        #  ifndef  identifier

elif-parts:
        elif-line  text
        elif-partsopt

elif-line:
        #  elif  constant-expression

else-part:
        else-line  text

else-line:
        #  else



이전 [▲ 맨위로]
[▧ 목차로]